Hoppa till innehållet

Cookieinställningar

Välj vilka typer av cookies du tillåter. Du kan alltid ändra ditt val via Cookieinställningar längst ned på varje sida. Integritetspolicy

Nödvändiga

Alltid på

Behövs för att logga in, spara din varukorg och komma ihåg dina val. De är alltid på.

Vilka cookies?
  • weboke_sessie, weboke_klant, weboke_remember: din session och att du förblir inloggad
  • weboke_basket: din varukorg
  • wkBtwIncl: visa priser med eller utan moms
  • wok_cookies: ditt cookieval, 12 månader

Mäter vilken annons som leder till ett besök eller en beställning, så att vi inte betalar för annonser som inte ger något.

Vilka cookies?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), upp till 90 dagar
  • OpenAI Ads, annonser i ChatGPT
  • wok_aff: via vilken partner du kom till oss (affiliateprogram), 60 dagar

4,6

Land och språk

Varje land har en egen webbplats med landets priser och moms.

Visa

Hämta gata, husnummer och tillägg ur en adresskolumn

Adresser från en webbutik, ett medlemsregister eller en gammal kundfil står ofta i en enda kolumn: "Dorpsstraat 12-2". För fraktetiketter, ett utskick eller en import hos ett transportföretag behöver gata, husnummer och tillägg stå var för sig. Med Text till kolumner fungerar det dåligt, eftersom gatunamn själva innehåller mellanslag. Hur du delar upp för- och efternamn läser du i Förnamn och efternamn från en kolumn dela upp; adresser är knepigare. Euro-Office har därför funktionerna REGEXUTDRAG och REGEXERSÄTT, som arbetar med ett sökmönster.

Som exempel tar vi kundlistan från Bloemisterij Het Zonnetje, med följande i kolumn A:

  • Koningin Julianalaan 15 a
  • Dorpsstraat 12-2
  • Laan 1940-1945 8B
  • Kerkplein 7
  • Hoofdstraat 120 bis

Steg 1: husnumret med tillägg

Skriv i B2:

=REGEXUTDRAG(A2;"\d+\S*( ?[A-Za-z]{1,3})?$")

Mönstret inom citattecknen betyder: en eller flera siffror (\d+), därefter eventuellt tecken utan mellanslag (\S*, till exempel -2 eller B), därefter eventuellt ett mellanslag med 1 till 3 bokstäver (till exempel " a" eller " bis"), och allt detta helt i slutet av texten ($). Resultat: 15 a, 12-2, 8B, 7 och 120 bis. Årtalen i "Laan 1940-1945" påverkas inte, eftersom bara den sista delen av adressen räknas.

Steg 2: gatan

Skriv i C2:

=RENSA(REGEXERSÄTT(A2;"\d+\S*( ?[A-Za-z]{1,3})?$";""))

REGEXERSÄTT ersätter samma del med ingenting, och RENSA tar bort mellanslaget i slutet. Kvar blir Koningin Julianalaan, Dorpsstraat, Laan 1940-1945 och så vidare.

Steg 3: nummer och tillägg för sig

Behöver även numret och tillägget stå var för sig, arbetar du vidare med resultatet från steg 1 i B2:

  • Bara numret, i D2: =REGEXUTDRAG(B2;"^\d+") (siffrorna i början): 15, 12, 8, 7, 120.
  • Tillägget, i E2: =RENSA(REGEXERSÄTT(B2;"^\d+[- ]?";"")): a, 2, B, ingenting, bis.

Dra sedan ner formlerna till sista raden. Eller arbeta kolumn för kolumn: markera till exempel B2:B6, skriv formeln och tryck på Ctrl+Enter; då hamnar den i alla markerade celler på en gång.

Adresser uppdelade i gata, nummer och tillägg
Husnummer med tillägg (1), gata (2), nummer (3) och tillägg (4), var och en med en enda formel

En adress med kommatecken

Står hela adressen i en cell, till exempel "Dorpsstraat 12, 1234 AB Utrecht", delar =DELATEXT(A9;", ") upp den vid kommatecknet: "Dorpsstraat 12" hamnar i själva cellen och "1234 AB Utrecht" i cellen bredvid. Postnummer och ort skiljer du sedan åt med TEXTFÖRE och TEXTEFTER, som hämtar texten före eller efter en viss förekomst av avgränsaren. Om "1234 AB Utrecht" står i C9:

  • Postnummer: =TEXTFÖRE(C9;" ";2) ger 1234 AB (allt före det andra mellanslaget).
  • Ort: =TEXTEFTER(C9;" ";2) ger Utrecht.

Klar? Gör om dem till fasta värden

De uppdelade kolumnerna är formler som hämtar från kolumn A. Vill du ta bort kolumn A, eller skicka filen till någon med en äldre version av Excel, gör då om resultaten till vanlig text: markera kolumnerna, kopiera dem med Ctrl+C och klistra in dem på samma ställe med Ctrl+V. Under de inklistrade cellerna visas en liten knapp (Ctrl). Klicka på den och välj Klistra in endast värde under Värde.

Inklistringsalternativen efter inklistring
Knappen (Ctrl) under de inklistrade cellerna, med valet Klistra in endast värde under Värde

Fallgropar

  • Undantag finns alltid kvar: "Postbus 12", "Hoofdstraat 3 hs", "tegenover 14". Sätt ett filter på kolumnerna och leta efter tomma eller konstiga resultat innan du använder listan.
  • Versaler: mönstret [A-Za-z] tar med både gemener och versaler. Använder du bara [a-z] faller 8B bort.
  • #SAKNAS! vid REGEXUTDRAG betyder att mönstret inte finns, till exempel i en adress utan husnummer.
  • Andra kalkylprogram: Excel har dessa REGEX-funktioner bara i nyare versioner av Microsoft 365. En kollega med en äldre version ser #NAMN?. Gör då först om resultaten till värden.
  • Det går även utan REGEX, men med fler begränsningar: =TEXTEFTER(A2;" ";-1) ger allt efter det sista mellanslaget. Det fungerar för "Kerkplein 7" och "Dorpsstraat 12-2", men för "15 a" får du bara a.

Ett ögonblick…

Ställ in dina domäner

Ställ in namnservrar, koppling till ditt webbhotell och vem som blir innehavare för varje domän.

Hämtar dina domäner…